// This a test program, no warranties are implied or given. PWM BMW ext temp sensor V1
// Use, copy any modify this test program any way you want, at your own risk. Then test, test, test
// It reads a extermal 10K thermister temperature probe and controls a BMW PWM fan.
// BMW fan: 5% duty = full, 95% = off, no PWM = full Freq = 100Hz, PWM signal is 12 volt, Temps in Centigrade
#include <PWM.h>
/*----------------------- User adjustable variables and preferences section ---------------------------------*/
// FYI a PWM duty ranges from 0 to 255. Set desired temperature range below
const int tempForFanStartup = 74; // target low temp. below this temperature, the fan will be off
const int tempForFanOnFull = 99; // target High temp. above this temperature, the fan will be on at full power

// adjust these for PWN to for fan off, fan start and fan full on
const int fanOnFullDuty = 26; // duty for 10% (full speed = 10% of 255)
const int fanDutyOff = 242; // duty for 95% (off fan speed = 95% of 255)

/*----------------------- end of User adjustable variables and preferences -----------------------------------*/
const int fanPwmOutPin = 9; // Arduino forces this pin to 0 or 5 volts.
const int tempSensorPin = A0; // Pin to read analog voltage from the temp sensor.

void setup() { /* ++++++++++++++++++ Setup is run once when the arduino boots ++++++++++++++++++++++++++*/
Serial.begin(115200); // set up serial port for 115200 baud (optional)
InitTimersSafe(); // set pwm frequency to 100 Hz for BMW pwm
SetPinFrequency(fanPwmOutPin, 100); // set pwm frequency to 100 Hz for BMW pwm
pwmWrite(fanPwmOutPin, 0); // start with fan off
analogReference (EXTERNAL); // note, this is using the 3.3 volt supply as the analog reference for more accuracy.
} // end setup

void loop() { /* ++++++++++++++++++ Main Loop, continuously loops forever ++++++++++++++++++++++++++++*/
int currTempC = get_temperature_sensor(); // read and translate the temp sensor
int pwmDuty = calculate_PWM_duty(currTempC); // calculate the needed pwm
pwmWrite(fanPwmOutPin, 255 - pwmDuty); // send PWM to output pin (invert pwm for 12 volt transistor)
Serial.print(F("Temp C: ")); Serial.print(currTempC);
Serial.print(F(" pwmDuty: ")); Serial.println(pwmDuty);
delay(1000);
} // end main loop

int calculate_PWM_duty(int currTemp) { /* ++++++++ subroutine to calculate and set PWM duty cycle ++++++++++++++*/
int duty = map(currTemp, tempForFanStartup, tempForFanOnFull, fanDutyOff, fanOnFullDuty ); // calc PWM Duty
int contrainedDuty = constrain(duty, fanOnFullDuty, 255 ); // PWM duty is never allowed ouside of min or max duties
return(contrainedDuty);
} // end calculate_PWM_duty

int get_temperature_sensor() {/* +++++ returns temp for extermal 10K thermister temperature probe ++++++++++*/
float R0 = 10000; // The base resistance of the NTC sensor used. 10K with a 3435 Beta.
float Beta = 3435; // The Beta of the sensor used. Very commonly available
int tmp = analogRead(tempSensorPin); // read temperature sensor (range 0 to 1023)
float r = ((1023.0*R0)/(float)tmp)-R0; // for a 10K thermister with a beta of 3435
tmp = (int) (Beta/log(r/0.09919) - 273.15 + .499); // for a 10K thermister with a beta of 3435
return(tmp);
} // end get_temperature_sensor